stackf.v

スタック

パラメータ

入出力ポート

PUSH命令(メモリから読み出したデータをスタックにプッシュ)を1クロックサイクルで実行するために，thruとdthruを導入．
メモリから読み出すのに1サイクル必要で，その読み出したデータをスタックトップに書き込むのにさらに１サイクル必要となる．そこでスタックに書き込むかわりに，メモリからの読み出しデータをdthruに入力し，それをスタックトップqtopの値とする．つまり，フリップフロップq[0]に書かれているスタックトップの値をスルーして，メモリの出力をスタックトップqtopとして出力する．

ソースコード

module stack(clk, reset, load, push, pop, thru, d, dthru, qtop, qnext);
  parameter N = 8;
	 
  input clk, reset, load, push, pop, thru;
  input [15:0] d, dthru;
  output [15:0] qtop, qnext;
  reg [15:0] q [0:N-1];

  assign qtop = (thru ? dthru : q[0]);
  assign qnext = q[1];
   
  always @(posedge clk or negedge reset)
    if(!reset) q[0] <= 0;
    else if(load) q[0] <= d;
    else if(pop) q[0] <= q[1];
    else q[0] <= qtop;

  always @(posedge clk or negedge reset)
    if(!reset) q[1] <= 0;
    else if(push) q[1] <= qtop;
    else if(pop) q[1] <= q[2];

  integer i;
  always @(posedge clk or negedge reset)
    for(i=2;i<N-1;i=i+1)
      if(!reset) q[i] <= 0;
      else if(push) q[i] <= q[i-1];
      else if(pop) q[i] <= q[i+1];
  
  always @(posedge clk or negedge reset)
    if(!reset) q[N-1] <= 0;
    else if(push) q[N-1] <= q[N-2];

endmodule